43. (MSSQL/SQL) 프로시저 (procedure) 생성 및 select 조회 결과 확인

---

[개발 환경 설정]

​

개발 툴 : SSMS

개발 언어 : MSSQL

 

---

[소스 코드]

​

/***************************************************************/


--CREATE PROCEDURE USER_PROC -- [생성]
ALTER PROCEDURE USER_PROC -- [수정]
(
	@IN_NAME NVARCHAR(100), -- [인풋 : 이름]
	@IN_AGE NVARCHAR(100), -- [인풋 : 나이]

	@OUT_RETURN INT OUTPUT -- [출력 : 파라미터]
)


/***************************************************************
설명 - 이름과 나이를 인풋값으로 받아서 해당 조건에 만족하는 사용자 정보 반환 실시
---------------------------------------------------------------
프로시저 생성 조회 : sp_helptext 'dbo.USER_PROC'
---------------------------------------------------------------
프로시저 호출 : 

-- [변수 선언]
DECLARE @IN_NAME NVARCHAR(100);
DECLARE @IN_AGE NVARCHAR(100);
DECLARE @OUT_RETURN INT;


-- [인풋 값 대입 실시]
SET @IN_NAME = '홍길동';
SET @IN_AGE = '35';
 

-- [프로시저 호출]
EXEC USER_PROC @IN_NAME, @IN_AGE, @OUT_RETURN OUTPUT;
 

-- [OUTPUT 리턴 상태 확인]
SELECT @OUT_RETURN AS '프로시저 수행 결과';
---------------------------------------------------------------              
프로시저 삭제 : DROP PROCEDURE USER_PROC
***************************************************************/  


AS


/**************** [프로시저 전역 변수 선언 실시] ***************/
DECLARE @V_STEP NVARCHAR(100);
DECLARE @V_MSG NVARCHAR(500);
DECLARE @V_DATE NVARCHAR(100);


/************** [프로시저 동작 쿼리문 작성 실시] ***************/
BEGIN TRY

	/*=========================================================*/

	-- [로직 : 스텝 저장]
	SET @V_STEP = '1';


	-- [프로시저 수행 날짜 및 시간 확인]
	SET @V_DATE = CONVERT(CHAR(19), getDate(), 20);

	/*=========================================================*/

	-- [로직 : 스텝 저장]
	SET @V_STEP = '2';


	-- [사전 인풋 데이터 체크 수행 실시]
	IF LEN(TRIM(@IN_NAME)) = 0 OR TRIM(@IN_NAME) = '' OR LEN(TRIM(@IN_AGE)) = 0 OR TRIM(@IN_AGE) = ''
	BEGIN    
		-- [메시지 출력]
		SET @V_MSG = 'N: 인풋 데이터 값을 확인해 주세요. [STEP = ' + @V_STEP + '] ' + '[' + @V_DATE + ']';
		PRINT '========================================='
		PRINT @V_MSG
		PRINT '========================================='

		-- [리턴 수행 : RETURN 값에는 정수만 가능]
		SET @OUT_RETURN = 0;
		RETURN (@OUT_RETURN);
	END

	/*=========================================================*/

	-- [로직 : 스텝 저장]
	SET @V_STEP = '3';


    -- [인풋으로 들어온 데이터 값에 맞게 조회 수행 실시]
    SELECT *
	    FROM TEST_USER
	WHERE T_NAME = @IN_NAME
	   AND T_AGE = @IN_AGE;

	-- [메시지 출력]
	SET @V_MSG = 'Y: 정상 처리 되었습니다. [STEP = ' + @V_STEP + '] ' + '[' + @V_DATE + ']';
	PRINT '========================================='
	PRINT @V_MSG
	PRINT '========================================='

	-- [리턴 수행 : RETURN 값에는 정수만 가능]
	SET @OUT_RETURN = 1;
	RETURN (@OUT_RETURN);

	/*=========================================================*/

END TRY


/************** [프로시저 예외 발생 처리 실시] ***************/
BEGIN CATCH
	-- [메시지 출력]
	SET @V_MSG = 'N: 예외 상황이 발생했습니다. [STEP = ' + @V_STEP + '] ' + '[' + @V_DATE + ']';
	PRINT '========================================='
	PRINT @V_MSG
	PRINT '========================================='

	-- [리턴 수행 : RETURN 값에는 정수만 가능]
	SET @OUT_RETURN = 0;
	RETURN (@OUT_RETURN);
END CATCH


/**************** [프로시저 종료 처리 부분] ******************/
GO
/*************************************************************/

 

---

[결과 출력]

​

 

---